buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        google()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:$gradleVersion"
    }
}

tasks.register('writeAllAssetsToFile') {
    doLast {
        def assetsFolder = new File("${project.rootDir}/assets/")
        def assetsFile = new File(assetsFolder, "assets.txt")
        assetsFile.delete()

        fileTree(assetsFolder).collect { assetsFolder.relativePath(it) }.each {
            assetsFile.append(it + "\n")
        }
    }
}

allprojects {
    apply plugin: "eclipse"

    version = '1.2'
    ext.appName = "maxon"

    repositories {
        mavenLocal()
        mavenCentral()
        google()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
        maven { url "https://jitpack.io" }
    }
}

project(":desktop") {
    apply plugin: "java-library"

    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
    }
}

project(":android") {
    apply plugin: "android"

    configurations { natives }

    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-android:$gdxVersion"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-armeabi-v7a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-arm64-v8a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86_64"
        implementation "androidx.core:core:$androidXVersion"
        implementation "com.google.android.gms:play-services-ads:$playAdsVersion"
    }
}

project(":shared") {
    apply plugin: "java-library"

    dependencies {}
}

project(":server") {
    apply plugin: "java-library"

    dependencies {
        implementation project(":shared")
        implementation "com.google.code.gson:gson:$gsonVersion"
        implementation "org.slf4j:slf4j-api:$slf4jVersion"
        implementation "ch.qos.logback:logback-classic:$logbackVersion"
        implementation "ch.qos.logback:logback-core:$logbackVersion"
        implementation "org.java-websocket:Java-WebSocket:$websocketVersion"
    }
}

project(":core") {
    apply plugin: "java-library"

    dependencies {
        implementation project(":shared")
        api "com.badlogicgames.gdx:gdx:$gdxVersion"
        api "de.golfgl.gdxgamesvcs:gdx-gamesvcs-core:$gamesvcsVersion"
        api "com.github.mgsx-dev.gdx-gltf:gltf:$gltfVersion"
        implementation "com.google.code.gson:gson:$gsonVersion"
        implementation "org.slf4j:slf4j-api:$slf4jVersion"
        implementation "ch.qos.logback:logback-classic:$logbackVersion"
        implementation "ch.qos.logback:logback-core:$logbackVersion"
        implementation "com.github.JnCrMx:discord-game-sdk4j:$discordSdkVersion"
        implementation "org.java-websocket:Java-WebSocket:$websocketVersion"
    }

    compileJava.dependsOn writeAllAssetsToFile
}